// ClothRay example: nappe.pov
// Christophe Bouffartigue (tofbouf@free.fr)

#version unofficial MegaPov 0.7;

#include "clothutil.inc"

#macro WriteClothFile(nomfile, n1, n2, nlng, ks, ht)

	#debug "\nWriting new .cth file\n"
	#fopen file nomfile write
	#write(file, n1, ",", n2, ",", nlng, ",", ks, ",\n")

	#local l1 = nlng*(n1-1);
	#local l2 = nlng*(n2-1);
	#local st = seed(1234);
	#local i=0;
	#while (i<n1)
		#local j=0;
		#while (j<n2)
			#local tempz = -l1/2 + i*nlng;
			#local tempy = -l2/2 + j*nlng + ht;
            #local tempx = (-1+2*rand(st))*nlng*.05;
			#write(file, tempx, ",", tempy, ",", tempz, ", 0.0, 0.0, 0.0,\n")
			#local j=j+1;
		#end
		#local i=i+1;
	#end

	#fclose file
#end



#declare Sol = union {
	plane { y, 0 }
}

//WriteClothFile("selfco.cth", 7, 150, 40/150, 50, 19)

simcloth {
	environment Sol
	friction    0.1

	gravity     -1*y

	neighbors   1
	internal_collision on
	damping     0.80
	intervals   0.04
	iterations  50

	input       "selfco.cth"
	output      "selfco.cth"
	mesh_output "selfco_s.msh"
	smooth_mesh on
	uv_mesh     on
}


#declare Machin = mesh {
	#include "selfco_s.msh"
	uv_mapping
	texture {
		pigment {
			checker
			color rgb <.75, .85, 1> , color rgb <.55, .7, 1>
		}
		scale <1/2, 1/20, 1>
	}
	finish { ambient .3 diffuse .7 }
	scale <1, 1, 1.5>
}


camera {location <15, 8, -45> angle 18 look_at 1*y }

light_source { <-10, 100, -100>, color rgb .5 shadowless }

light_source { <80, 90, -50>*3, color rgb 1.1
	spotlight
	radius 20
	falloff 30
	tightness 2
	point_at 0
}


object { Machin }
object { Sol translate -.01*y
	pigment { rgb .85 }
	finish { ambient .3 diffuse .7 }
}