// ClothRay example: nappe.pov
// Christophe Bouffartigue (tofbouf@free.fr)

#version unofficial MegaPov 0.7;

#include "clothutil.inc"

#macro WriteClothFile(nomfile, n1, n2, nlng, ks, ht)

	#debug "\nWriting new .cth file\n"
	#fopen file nomfile write
	#write(file, n1, ",", n2, ",", nlng, ",", ks, ",\n")

	#local l1 = nlng*(n1-1);
	#local l2 = nlng*(n2-1);
	#local st = seed(1234);
	#local i=0;
	#while (i<n1)
		#local j=0;
		#while (j<n2)
			#local tempx = -l1/2 + i*nlng;
			#local tempy = -l2/2 + j*nlng;
            #local tempz = ht + (-1+2*rand(st))*nlng*0.01;
			#write(file, tempx, ",", tempy, ",", tempz, ", 0.0, 0.0, 0.0,\n")
			#local j=j+1;
		#end
		#local i=i+1;
	#end

	#fclose file
#end



/* write initial file */
#macro WriteInitialDrapeau()
WriteClothFile("attach.cth", 40, 40, .5, 100, 0)

	#fopen file "attach.cth" append

	#write(file, 39, ", 0.0, 0.0, 0.0,\n")
	#write(file, 38, ", 0.5, 0.5, 0.5,\n")
	#write(file, 40+38, ", 0.5, 0.5, 0.5,\n")
	#write(file, 40+39, ", 0.5, 0.5, 0.5,\n")

	#fclose file

#end



//WriteInitialDrapeau()


simcloth {

	gravity     -0.4*y

	neighbors   1
	internal_collision off
	damping     0.95
	intervals   0.04
	iterations  200

	input       "attach.cth"
	output      "attach.cth"
	mesh_output "attach_s.msh"
	smooth_mesh on
	uv_mesh     on
}



#declare Drapeau = mesh {
	#include "attach_s.msh"
	uv_mapping
	texture {
		pigment {
			checker
			color rgb <1,.5, .2>, color rgb <.9, .85, .4>
			scale <1/10, 1/10, 1>
		}
		finish { ambient .3 diffuse .7 }
	}
}

camera {location <30, 10, -90> angle 30 look_at 0*x }

light_source { 10000*y, color rgb 1.2
	rotate -x*30
	rotate y*45
}


object { Drapeau }